EXPORTER DES GRAPHIQUES D'UN FICHIER EXCEL EN IMAGES

Commentaire de Renfield le 23/05/2007 17:19:27 administrateur CS

ton .Activate n'est pas utile, tu peux directement demander la propriété Chart de ton CharObject obtenu via ChartObjects(i).



en gros, ton code pourrait être :


Private Declare Function MkDir Lib "imagehlp.dll" Alias "MakeSureDirectoryPathExists" (ByVal lpPath As String) As Long

Sub test()
    ExportGraphs "C:\test"
End Sub

Sub ExportGraphs(ByVal vsDestPath As String)
Dim oSheet As Worksheet
Dim i As Long
    If Right$(vsDestPath, 1) <> "\" Then
        vsDestPath = vsDestPath & "\"
    End If
    
    MkDir vsDestPath
    
    For Each oSheet In ActiveWorkbook.Sheets
        ' On parcours les graphiques de la feuille
        For i = 1 To oSheet.ChartObjects.Count
            With oSheet.ChartObjects(i).Chart
                .Export vsDestPath & .Name & ".gif", "GIF"
            End With
        Next i
    Next oSheet
End Sub

Commentaire de Renfield le 24/05/2007 09:48:22 administrateur CS

je répète :
"ton .Activate n'est pas utile, tu peux directement demander la propriété Chart de ton CharObject obtenu via ChartObjects(i)."

sans le Activate, donc :
            NomGraph = Sheets.ChartObjects(i).Chart.Name


d'où mon code :
            With oSheet.ChartObjects(i).Chart
                .Export vsDestPath & .Name & ".gif", "GIF"
            End With


au fait, sous Windows, les chemins c'est avec des '\', pas des '/' ^^

Commentaire de PhilippeF66 le 19/06/2007 18:21:02

Bonjour à tous,
le problème de ce code (dans mes applications) est que quelle que soit la façon dont j'arrive à la ligne "export" (mon contexte de code est différent), la méthode export provoque une erreur 1004...
rien à faire pour passer outre
idem avec la méthode SaveAS
"y'a queq'chose qui cloche" comme disait B. Vian, mais quoi ?

Commentaire de Renfield le 20/06/2007 22:51:15 administrateur CS

quel message, l'erreur 1004 ?

Commentaire de Renfield le 21/06/2007 08:08:37 administrateur CS

Je pense que le chemin du gif n'est pas correct.
qu'a tu mis ?

quelques pistes, pour tester ........


quellle version d'office ?

est tu admin de ton poste ?
si non, est-ce que tu peux tenter en passant avec un  compte admin ?

le chemin du gif est il correct ?
le fichier gif existe peut etre (lecture seule ou non) et empeche la recreation
peut etre une histoire de droit dans le repertoire cible

as tu essayé mon code, ou celui de roro59650

le FileName ne peut exceder 255 caractères

aurais tu un AddIn sur ton Office, qui pourrais empecher l'export ?

esssaye d'exporter en jpg plutot qu'en gif

as tu excel 2007 qui cohabiterais avec ton excel classsique ?

je te laisse consulter :
http://groups.google.com/groups?q=chart+export+1004&start=0&hl=fr&

Commentaire de Renfield le 29/06/2007 01:13:07 administrateur CS

fais le test, c'est le plus simple :p

Commentaire de Renfield le 29/06/2007 09:39:56 administrateur CS

les modifications ne sont pas très lourdes...




Private Declare Function MkDir Lib "imagehlp.dll" Alias "MakeSureDirectoryPathExists" (ByVal lpPath As String) As Long

Sub test()
    ExportGraphs "C:\test"
End Sub

Sub ExportGraphs(ByVal vsDestPath As String)
Dim oSheet As Object
Dim i As Long
    If Right$(vsDestPath, 1) <> "\" Then
        vsDestPath = vsDestPath & "\"
    End If
    
    MkDir vsDestPath
    
    For Each oSheet In ActiveWorkbook.Sheets
        If TypeOf oSheet Is Worksheet Then
            ' On parcours les graphiques de la feuille
            For i = 1 To oSheet.ChartObjects.Count
                With oSheet.ChartObjects(i).Chart
                    .Export vsDestPath & .Name & ".gif", "GIF"
                End With
            Next i
        ElseIf TypeOf oSheet Is Chart Then
            With oSheet
                .Export vsDestPath & .Name & ".gif", "GIF"
            End With
        End If
    Next oSheet
End Sub

Commentaire de PhilippeF66 le 02/07/2007 21:14:09

Merci Renfield,
J'ai été absent qqs jours et n'ai pu répondre.
La même erreur se produit dans les mêmes circonstances, que je sois sur mon PC professionnel (je ne suis pas administrateur et il est en réseau) ou que je sois sur mon PC personnel dont je suis administrateur.
J'utilise Excel 2003 (suite Office Pro 2003).
Il n'y a pas de problème sur le nom du fichier image, ni sur son chemin, ni sur la longueur du nom de l'ensemble chemin + fichier.
L'erreur existe que j'essaie en gif ou en jpg, quant à l'AddIn, je ne sais...
L'erreur existe tant avec mon code qu'avec le tien ou celui de Roro...
A+

Commentaire de Mohamedyounsi le 02/04/2008 11:36:49

Salut,
erreur d'exécution 91
"variable objet ou variable bloc With non définie"
ma question c'est quelle est ke type de déclaration de l'objet oSheet?
set oSheet = new .....

Merci de me répondre.

Commentaire de Mohamedyounsi le 02/04/2008 14:42:03

salut,

j'ai déclaré oSheet comme objet.
mais le même problème qui persiste
erreur d'exécution 91
"variable objet ou variable bloc With non définie" le problème est dans "ActiveWorkbook.sheets"

Merci de me répondre.