[VBA] OBTENIR L'HANDLE DE LA LISTE DÉROULANTE D'UN COMBOBOX D'UNE FEUILLE EXCEL

'-------------------------
' Dans une feuille excel :
'
Private Sub ComboBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    If hWndDropListCombo = 0 Then
        hWndDropListCombo = GetHandleDropListFromCombo
        ' ajoutez ici votre code pour utiliser cet handle
        ' ...
    End If
End Sub
Private Sub ComboBox1_LostFocus()
    hWndDropListCombo = 0
End Sub


'-----------------
' Dans un module :
'
Public hWndDropListCombo As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Public Function GetHandleDropListFromCombo() As Long
    Dim hWndExcel As Long
    Dim hWndPopup As Long
    Dim hWndList As Long
    Const VBA_POPUP_CLASSNAME = "F3 MdcPopup 60000000"
    Const VBA_LIST_CLASSNAME = "F3 Server 60000000"
    ' retourne l'handle d'excel
    hWndExcel = FindWindow("XLMAIN", vbNullString)
    'trouve celui du popup
    hWndPopup = FindWindowEx(hWndExcel, 0&, VBA_POPUP_CLASSNAME, vbNullString)
    If hWndPopup = 0 Then
        hWndPopup = FindWindow(VBA_POPUP_CLASSNAME, vbNullString)
    End If
    'trouve celui de la liste dans le popup
    hWndList = FindWindowEx(hWndPopup, 0&, VBA_LIST_CLASSNAME, vbNullString)
    GetHandleDropListFromCombo = hWndList
End Function