Création de graphique

Bonjour !!
J'aimerais de l'aide si possible !! Voila, j'ai des graphiques à réaliser sur excel !! Les données du graphique prennent sources dans un tableau qui lui même prend source dans une base de données access ! De ce fait, plus le temps passe, plus j'ai de données et plus mon tableau s'agrandit ! Ce que j'aimerais faire c'est faire un test pour savoir jusqu'où mon tableau va et ensuite faire mon graphique avec les données de la cellules A2 à tel colonne et la ligne maximum qu'il y a ! Mais je ne sait pas comment m'y prendre !! Si quelqu'un pouvait m'aider cela m'arrangerait ! Voici le code que j'ai pour l'instant :

Sub grafik10()

    Charts.Add
    ActiveChart.ChartType = xlLineMarkers
    ActiveChart.SetSourceData Source:=Sheets("TableauSportif").Range("N2:O3"), _
        PlotBy:=xlRows
    ActiveChart.Location Where:=xlLocationAsObject, Name:="GraphComparaison"
    With ActiveChart
        .HasTitle = False
        .Axes(xlCategory, xlPrimary).HasTitle = False
        .Axes(xlValue, xlPrimary).HasTitle = False
    End With

End Sub

Salut,

3 methodes:

- la plus simple mais pas la plus efficace:

Dim DerniereCellule As Range
Set DerniereCellule = Worksheets("feuil1").Cells.SpecialCells(xlCellTypeLastCell)
MsgBox DerniereCellule.Address(False, False)

-2ieme solution:

Sub Adresse_Derniere_Cellule()
    Dim XLLigneMax As Long, XLColMax As Long
    Dim DerniereCellule As Range, Ligne As Long
   
    'pour une meilleur compatibilité XL2007 et les versions d'avant
    XLLigneMax = Columns(1).Rows.Count
    XLColMax = Rows(1).Columns.Count
   
    With Worksheets("feuil1")
        Ligne = .Range("A" & XLLigneMax).End(xlUp).Row
        Set DerniereCellule = .Range(IndexColonne(XLColMax) & Ligne).End(xlToLeft)
    End With
    MsgBox DerniereCellule.Address(False, False)
End Sub
Function IndexColonne(Optional ByVal NumCol As Long = 1) As String
    IndexColonne = Left(Columns(NumCol).Address(False, False), InStr(1, Columns(NumCol).Address(False, False), ":", vbTextCompare) - 1)
End Function

-3ieme solution qui parrait plus simple mais peu generer plus d'erreur

Sub Adresse_Derniere_Cellule()
    Dim DerniereCellule As Range
    Dim Ligne As Long, Col As Long
    With Worksheets("feuil1")
        Ligne = .Columns(1).Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Set DerniereCellule = .Rows(Ligne).Find(What:="*", SearchOrder:=xlByColumns, SearchDirection:=xlPrevious)
    End With
    MsgBox DerniereCellule.Address(False, False)
End Sub

A+

okay !! merci j'essaierais tout à l'heure !!