Bonjour,
Ci-dessous, en vbs, un script qui pourrait correspondre à vos attentes.
J'ai testé en local (xp).
J'attends vos remarques pour avancer sur servers + présentation Excel.
Comme d'hab, ce n'est pas trop commenté, mais les variables sont explicites,
et, il n'y a rien de bien compliqué.
Le fichier résultat (verif_NomServer.txt) est créé dans le répertoire du script.
jean-marc
________________________________________________________
Option Explicit
Const ForWriting = 2
Const HARD_DISK = 3
Dim WshNetwork, objWMIService, colDisks, colFiles, ObjTextStream
Dim strComputer, fso, Select_Ext, objDisk, objFile
Dim curtime, Resultat, i, FicOut
curtime=Now
strComputer = "."
Set WshNetwork = WScript.CreateObject("WScript.Network")
FicOut = GetPath() & "verif_" & WshNetwork.ComputerName & ".txt"
'MsgBox FicOut
Set WshNetwork = Nothing
Select_Ext = Array("xls","xlt","doc","dot","pdf","pps","ppt","htm","txt")
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colDisks = objWMIService.ExecQuery _
("Select * from Win32_LogicalDisk Where DriveType = " & HARD_DISK & "")
For Each objDisk in colDisks
For i=LBound(Select_Ext) To UBound(Select_Ext)
Set colFiles = objWMIService.ExecQuery _
("Select * from CIM_DataFile where Drive = '" &_
objDisk.Name & "' And Extension = '" & Select_Ext(i) &"'")
For Each objFile in colFiles
Resultat = Resultat &vbCrLf&_
objFile.Name &vbTab&vbTab& clair(objFile.LastModified)
Next
Next
Next
'MsgBox "fin read disks"
Set colFiles = Nothing
Set colDisks = Nothing
Set objWMIService = Nothing
'Création du fichier txt résultat
Set fso = CreateObject("Scripting.FileSystemObject")
Set ObjTextStream = Fso.OpenTextFile(FicOut, ForWriting, True)
ObjTextStream.Write "début script: " & curtime &vbCrLf&_
"fin script: " & Now &vbCrLf& Resultat
ObjTextStream.Close
Set ObjTextStream = Nothing
Set fso = Nothing
'Affichage du fichier résultat
Dim WshShell, intReturn
Set WshShell = WScript.CreateObject("WScript.Shell")
intReturn = WshShell.Run("notepad " & FicOut, 1, False)
Set WshShell = Nothing
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function clair(temps)
Dim debut, an, mois, jour, h, m
debut = left(temps,8)
an = left(debut,4)
mois = mid(debut,5,2)
jour = right(debut,2)
h = Mid(temps, 9,2)
m = Mid(temps, 11,2)
clair = CStr(jour) & "/" & CStr(mois) & "/" & CStr(an) & " " & h & ":" & m
End Function
'Récupère le répertoire courant
Function GetPath()
Dim path
'WScript.ScriptfullName ramène par exemple C:\MesAppli\LeScript.vbs
path = WScript.ScriptFullName
'On ne garde que ce qui est à gauche du dernier slash (compris), exemple C:\MesScripts\
GetPath = Left(path, InStrRev(path, "\"))
End Function