Rechercher du texte dans un fichier word sans l'ouvrir

Bonjour,
Je suis en train d'ecrire une petite fonction qui possede en parametres un nom de fichier, du texte et une variable resultat.
Je voudrais ouvrir le fichier, chercher s'il possede le texte et renvoyer 1 si il l'a trouve.
J'ai mis en commentaire les 2 lignes qui me posent probleme
Pour l'instant mon code donne ceci :

'fonction recherchant du texte dans un fichier
Function Recherche(Fichier As String, texte As String, result As Integer)

MsgBox Fichier
Open Fichier For Input As #1
Do Until EOF(1)
'Line Input #1, ligne
'If InStr(ligne, texte) <> 0 Then
result = 1
Exit Do
End If
Loop
Close #1

End Function

Merci de vos reponses.

Function Recherche(Fichier As String, texte As String) As Integer

'Déclaration de l'objet Word
Dim WrdApp As Object

'Initialisation
Recherche = 0

'Création de l'instance Word
Set WrdApp = CreateObject("Word.Application")

'S'assurer que l'appli Word est invisible
WrdApp.Visible = False

'Ouvrir le fichier
WrdApp.documents.Open Fichier

'Faire la recherche
With WrdApp.documents(Fichier).content.Find
.Text = texte
.Execute
If .Found = True Then Recherche = 1
End With

'Fermer le document sans enregistrer
WrdApp.documents(Fichier).Close False

'Quitter l'application Word
WrdApp.Quit
Set WrdApp = Nothing
End Function

Merci, c'est exactement ce qu'il me fallait!