A vrai dire je vois à peu prés le fonctionnement.Je sais creer un groupe dans un client et y ajouter des items.et sa a l'air de fonctionner puisque quand je clic sur les item du client la valeur est la bonne.J'ai également ajouter les dll comme tu me l'a expliqué.Maintenant,si j'ai bien compris,il n'y a plus que du code à écrire?J'ai trouvé un morceau de code sur le net mas je ne sais ou l'implanter.
C'est super sympa de m'aider.Merci beaucoup.
Voilà ce que j'ai trouvé en cherchant sur le net:
' -----------------------------------------------------------------------------------------
' Configuration de la communication avec Server OPC
' -----------------------------------------------------------------------------------------
Option Explicit
Dim WithEvents OpcFactoryServer As OPCServer 'Interface OPC Automation2 avec Notification
Dim ListOfsGroups As OPCGroups 'Objet pour une liste de groupes
Dim WithEvents Group1 As OPCGroup 'Objet pour un Groupe avec Notification
Dim PremierCollectionItems As OPCItems 'Objet pour une Collection d'Items
Dim Item1 As OPCItem 'Objet pour un Item
Dim ItemName1() As String 'Tableau de Définition des items
Dim HandleClient1() As Long 'Tableau de pointeurs des items Client
Dim HandleServer1() As Long 'Tableau de pointeurs des items Serveur
Dim Erreur1() As Long 'Tableau de codes d'erreur rendus par le Serveur
Dim FinCreation As Boolean 'Flag de signalement de la fin de création
Const ProgID = "Schneider-Aut.OFS" 'Type de Serveur OPC
Dim NomDuPoste As String 'Nom du PC Serveur
' ---------------------------------------------------------------------------------------------
' LANCEMENT DE L'APPLICATION
' ---------------------------------------------------------------------------------------------
Public Sub Start() ' Bouton start
Dim NbItem1 As Single
Dim Reponse As Integer
NbItem1 = 1
'Redimentionnement des tableaux en fonction du nombre d'item
ReDim ItemName1(NbItem1) As String
ReDim HandleClient1(NbItem1) As Long
ReDim HandleServer1(NbItem1) As Long
ReDim Erreur1(NbItem1) As Long
'Création des Groupes et items
If Not FinCreation Then
'Initialisation d'un Serveur OPC Automation 2.01
Set OpcFactoryServer = New OPCServer 'Connexion au Serveur OFS
On Error GoTo Label1 ' Si une erreur aller au label 1
OpcFactoryServer.Connect ProgID
OpcFactoryServer.ClientName = "Stage OFS" 'Spécifie le nom du Client OPC
Set ListOfsGroups = OpcFactoryServer.OPCGroups 'Crée une instance de ce Client
'Définit les paramètres par défaut du Groupe
ListOfsGroups.DefaultGroupIsActive = False
ListOfsGroups.DefaultGroupUpdateRate = 500 'ms
ListOfsGroups.DefaultGroupDeadband = 1
'Ajout des groupes dans le Serveur
Set Group1 = ListOfsGroups.Add("Group1")
'Crée des collections d'Items
Set PremierCollectionItems = Group1.OPCItems
'Définit les item en respectant la syntaxe OPC et le Pointeur coté Client (pompe)
'Vous devez créer un fichier *.csv dans lequel vous définissez les noms et adresses de l'automate.
'Vous l'ajoutez ensuite avec le configurateur OFS.
'Dans le code VBA, vous y accédez avec le nom du fichier (NomAlias) et le nom associé à l'adresse automate (NomAdresse).
ItemName1(1) = "NomAlias" & "!" & "NomAdresse"
HandleClient1(1) = 1
End If
'Activation de la collection d'items
PremierCollectionItems.DefaultIsActive = True
'Ajoute les items au Groupe et récupère le pointeur coté Serveur et le code Erreur
PremierCollectionItems.AddItems NbItem1, ItemName1, HandleClient1, HandleServer1, Erreur1
Set Item1 = PremierCollectionItems.GetOPCItem(HandleServer1(1))
'Activation du Groupe (lecture), validation de la notification, mise à 1 du Flag de Création
Group1.IsActive = True
Group1.IsSubscribed = True
FinCreation = True
Exit Sub
Label1:
'Reponse = MsgBox("Erreur dans le nom du Poste Distant !", vbCritical, "Attention !")
Call MsgBox(Err.Description, vbOKOnly)
Resume Next
End Sub
' ---------------------------------------------------------------------------------------------
' ARRET DE L'APPLICATION
' ---------------------------------------------------------------------------------------------
Public Sub Arret() ' Bouton stop
If Not (OpcFactoryServer Is Nothing) Then
'Supprimer tous les groupes OPC
If Not (ListOfsGroups Is Nothing) Then
Group1.IsSubscribed = True
ListOfsGroups.RemoveAll
Set ListOfsGroups = Nothing
End If
'Deconnecter le Serveur
OpcFactoryServer.Disconnect
Set OpcFactoryServer = Nothing
FinCreation = False
Else
'Vider les groupes, vider le Serveur
Set ListOfsGroups = Nothing
Set OpcFactoryServer = Nothing
End If
End Sub
' ---------------------------------------------------------------------------------------------
' RECUPERATION DES DONNEES DU GROUPE 1
' ---------------------------------------------------------------------------------------------
Private Sub Group1_DataChange(ByVal TransactionID As Long, ByVal NumItems As Long, ClientHandles() As Long, ItemValues() As Variant, Qualities() As Long, TimeStamps() As Date)
Dim ind As Long
'Tester la qualité de l'item
ind = 1
While ind <= NumItems
If Qualities(ind) = 192 Then
'Récupérer la valeur
Sheets("essai").Cells(1, 1) = ItemValues(ind)
Else
Sheets("essai").Cells(1, 1) = " ERREUR !"
End If
ind = ind + 1
Wend
End Sub
' ---------------------------------------------------------------------------------------------
' ECRITURE
' ---------------------------------------------------------------------------------------------
Public Sub ecrire()
Item1.Write (10)
End Sub