|
 Trouver une ressource
Vous ne trouvez pas de réponse à votre problème ? Alors posez la question dans le forum. Souvenez-vous qu'il n'y a jamais de question bête, mais rester dans l'ignorance parce que l'on n'ose pas poser une question, ça c'est une erreur !
 Sujet : Cacher application access lors de l'exec d'une bd [ Archives Visual Basic / J'AI BESOIN D'AIDE !!!! :) ] (cedric68)
 Informations & options pour cette discussion
|
jeudi 22 août 2002 à 10:49:22 |
Cacher application access lors de l'exec d'une bd
cedric68
|
je souhaite lors de l'execution de mon appli access cacher access et voir en plein ecran mes differents formulaires . Quelqu'un a une idee merci cedric 
|
|
|
|
jeudi 22 août 2002 à 16:03:28 |
Re : Cacher application access lors de l'exec d'une bd
iubito
|
Salut Cedric
il doit y avoir une option je ne sais plus où pour faire démarrer automatiquement un formulaire.
Donc tu peux faire démarrer automatiquement ton formulaire principal sans que l'utilisateur aie à double-clicker dessus... Par contre je ne sais plus où c'est (propriété de formulaire, options...)
|
|
|
|
vendredi 28 novembre 2003 à 00:11:48 |
Re : Cacher application access lors de l'exec d'une bd
ClickPouf
|
Salut gars ! J'ai trouvé une soluce à ton problème par hasard... C'est une bidouille, c'est pas beau, ça utilise certainement une erreur de chez microsoft... mais ça marche ! Tout d'abord déclarer les API suivantes dans un module.
'********************************************************************************************
'* ApiWindows : Déclaration des API Windows *
'********************************************************************************************
Option Compare Database
Option Explicit
' GetDesktopWindow : Donne le pointeur de la fenêtre du bureau
Public Declare Function GetDesktopWindow Lib "user32" ( _
) As Long
' GetParent : Donne le pointeur de la fenêtre parent
Public Declare Function GetParent Lib "user32" _
(ByVal hwnd As Long _
) As Long
' GetWindow : Donne le pointeur d'une fenêtre
Public Declare Function GetWindow Lib "user32" _
(ByVal hwnd As Long _
, ByVal wCmd As Long _
) As Long
Public Const GW_HWNDFIRST = 0 ' Pointeur de la première fenêtre
Public Const GW_HWNDNext = 2 ' Pointeur de la fenêtre suivante
' GetWindowRect : Donne le rectangle d'affichage de la fenêtre
Public Declare Function GetWindowRect Lib "user32" _
(ByVal hwnd As Long _
, lpRect As RECT _
) As Long
Public Type RECT ' Rectangle d'affichage de la fenêtre
left As Long
top As Long
right As Long
bottom As Long
End Type
' MoveWindow : Positionne et dimensionne la fenêtre
Public Declare Function MoveWindow Lib "user32" _
(ByVal hwnd As Long _
, ByVal x As Long _
, ByVal y As Long _
, ByVal nWidth As Long _
, ByVal nHeight As Long _
, ByVal bRepaint As Long _
) As Long
' ShowWindow : Défini le mode d'affichage de la fenêtre
Public Declare Function ShowWindow Lib "user32" _
(ByVal hwnd As Long _
, ByVal nCmdShow As Long _
) As Long
|
Ensuite définir ces deux fonctions
'********************************************************************************************
'* CommonFunctions : Fonctions communes du projet *
'********************************************************************************************
Option Compare Database
Option Explicit
'===== HideApplicationForm : Cacher la fenêtre application ==================================
Function HideApplicationForm(FormId As Form)
On Error GoTo Err_HideApplicationForm
Dim hwndApplication As Long ' Fenêtre de l'application
Dim lRect As RECT ' Dimension du bureau
Dim wWidth As Long ' Largeur du formulaire
Dim wHeight As Long ' Hauteur du formulaire
' Stocker le pointeur de le fenêtre principale
'---------------------------------------------
Application.Echo False
hwndApplication = GetParent(GetParent(GetWindow(FormId.hwnd, GW_HWNDFIRST)))
' Maximiser la fenêtre principale
'--------------------------------
ShowWindow hwndApplication, 3
' Stocker les dimensions du formulaire
'-------------------------------------
wWidth = FormId.WindowWidth
wHeight = FormId.WindowHeight
' Cacher puis restorer la fenêtre principale
'-------------------------------------------
ShowWindow hwndApplication, 0
ShowWindow hwndApplication, 1
' Stocker les dimensions du bureau
'---------------------------------
GetWindowRect GetDesktopWindow, lRect
' Dimensionner et centrer la fenêtre principale
'----------------------------------------------
If CurrentDb.Properties("StartUpShowStatusBar") = False Then
MoveWindow hwndApplication _
, (lRect.right - (wWidth / 15)) / 2 _
, (lRect.bottom - (wHeight / 15)) / 2 _
, wWidth / 15, wHeight / 15 _
, 1
Else
MoveWindow hwndApplication _
, (lRect.right - (wWidth / 15)) / 2 _
, (lRect.bottom - (wHeight / 15)) / 2 _
, (wWidth / 15), 20 + (wHeight / 15) _
, 1
End If
' Maximiser le formulaire
'------------------------
DoCmd.Maximize
' Sortie et Gestion des Erreurs
'------------------------------
Exit_HideApplicationForm:
Application.Echo True
Exit Function
Err_HideApplicationForm:
Select Case Err.Number
Case Else
MsgBox Err.Number & " " & "CommonFunctions" & " " _
& "HideApplicationForm" & " :" & vbLf _
& Nz(Err.Description, "") & vbLf _
& "Values : " & FormId.Name
End Select
Resume Exit_HideApplicationForm
End Function
'===== ShowApplicationForm : Cacher la fenêtre application ==================================
Function ShowApplicationForm(FormId As Form)
On Error GoTo Err_ShowApplicationForm
Dim hwndApplication As Long ' Fenêtre de l'application
' Stocker le pointeur de le fenêtre principale
'---------------------------------------------
Application.Echo False
hwndApplication = GetParent(GetParent(GetWindow(FormId.hwnd, GW_HWNDFIRST)))
' Cacher, afficher puis maximiser la fenêtre principale
'------------------------------------------------------
ShowWindow hwndApplication, 0
ShowWindow hwndApplication, 1
ShowWindow hwndApplication, 3
' Sortie et Gestion des Erreurs
'------------------------------
Exit_ShowApplicationForm:
Application.Echo True
Exit Function
Err_ShowApplicationForm:
Select Case Err.Number
Case Else
MsgBox Err.Number & " " & "CommonFunctions" & " " _
& "ShowApplicationForm" & " :" & vbLf _
& Nz(Err.Description, "") & vbLf _
& "Values : " & FormId.Name
End Select
Resume Exit_ShowApplicationForm
End Function
|
Pour cacher la fenêtre principale, appelle la fonction HideApplicationForm à partir de ton formulaire d'ouverture (dans Open_Form par ex). Attention ! N'oublie pas de créer un bouton, un évènement ou un code touche qui appelle la fonction ShowApplicationForm... Parce que là t'auras plus accès à ta base !!! Tu pourras toujours l'importer dans une autre au cas où. A+
|
|
|
|
samedi 28 mai 2005 à 13:35:13 |
Re : Cacher application access lors de l'exec d'une bd
luxey
|
tu peu simplement utiliser les obtions de démarages et metre les form en max et independante
|
|
|
Cette discussion est classé dans : access, bd, application, cacher, exec
 Répondre à ce message
 Sujets en rapport avec ce message
empaqueter une application VB avec sa BD Access [ par alaindelan ]
J'ai une application VB6.0 empaqueter mais le problème c que je dois à chaque fois lorsque je l'installe de copier la
BD accesss dans VB.net [ par ouija33 ]
Bonjour a tous, je tente d'ouvrir une BD access dans un programme simple en VB.NET. alores je vais dans donnée, ajouter une nouvelle source d
Cacher la barre bleu de l'application [ par soundpanther ]
Bonjour tlm C'est mon premier messageVoilà j'ai un problème au niveau de la barre bleu de mon application car j'essaye de faire un petit Skin, mais il
base de donnee access [ par hafsoit ]
bonjour, je suis entrain de concevoir une application sous vb et comme base de donnee Access 2000,il s agit d'une application de gestion de stock.et
Boite de texte en html en connexion avec bd access [ par skweek ]
Bonjour,Je dispose d'une BD Access contenant des champs avec des liens hypertextes. Celle-ci me sert à ouvrir facilement des fichiers dans des réperto
transfert bd sur excell ou access [ par bechbech1308 ]
Bonjour, je serais à la recherche d'information, d'aide, voila j'ai un logiciel qui utilise une base de donnée access. j'aimerais transférer cette bas
Références en access vba [ par DomVB ]
bien le bonjourj'ai une base de données Access 2003 qui pilote des classeurs excel et des documents word.J'ai préparé une sub d'initialisation en vba
DAO et Date [ par ben333 ]
Bonjour, je suis en train de créer une application VB avec accès DAO (Access).De mon application, je permets à l'utilisateur de choisir une date via p
Problème d'acces à une BD protégée par mot de passe [ par petitcaro112 ]
Bonjour !N'ayant pas trouvé de réponse à ma question sur les forum (peut être une mauvaise recherche...), je me permet de la poser :- J'ai une BD acce
rendre une application VB/Access, client serveur [ par bchibicha ]
Salut tout le monde Pour moi j'ai réalisé une application VB/Access, cette application fonctionne bien mais le problème c'est que mon supérieur m'as
 Livres en rapport
|
 Téléchargements
Logiciels à télécharger sur le même thème :
|